Visual FoxPro ODBC driver was last updated around VFP6 SP3. It supports a subset of VFP 6.0 features but not any new ones introduced in VFP7 and later. See VFP 6.0 Help file and Unsupported Visual FoxPro Commands and Functions (Visual FoxPro ODBC Driver) for additional information. It'll not recognize any tables that use VFP7 and later new features and either ignore them or give an error when trying to access them.

The VFP ODBC driver was included in MDAC 2.5 and earlier and preinstalled on Windows 2000 and earlier. In order to use it on Windows XP and later Windows versions, it has to be installed first. The Microsoft Visual FoxPro Driver 6.01.8629.01 is available for download at http://msdn.microsoft.com/en-us/vfoxpro/bb190233.aspx.

The VFP ODBC Driver can be installed under 64-bit Windows but 64-bit applications cannot access VFP ODBC driver because it comes only in 32-bit version. For 32-bit applications under 64-bit Windows there's ODBC Data Source Administrator for the 32-bit ODBC drivers %systemdrive%\Windows\SysWoW64\odbcad32.exe (usually C:\WINDOWS\SysWOW64\odbcad32.exe).

The code below shows how to use VFP ODBC in SPT with DSN-less connection.

CLEAR
 
* Attempt to access Northwind.dbc with VFP ODBC driver will generate the error below because the DBC has DBC events enabled:
*  Connectivity error: [Microsoft][ODBC Visual FoxPro Driver]File was created in a later version of Visual FoxPro than the current version.
*lcDbc = HOME(2) + "Northwind\Northwind.dbc"
 
lcDbc = HOME(2) + "Data\testdata.dbc"
 
TEXT TO lcConnStr TEXTMERGE NOSHOW
DRIVER=Microsoft FoxPro VFP Driver (*.dbf); 
	Deleted=Yes; Null=Yes; Collate=Machine;
	BackgroundFetch=No; Exclusive=No; 
	SourceType=DBC; SourceDB=<<lcDbc>>
ENDTEXT			
 
lnConn = SqlStringConnect(lcConnStr)
IF lnConn < 0
	=AERROR(laError)
	? laError[1,2]
	RETURN
ENDIF	
 
TEXT TO lcSql NOSHOW
SELECT * FROM Products 
ENDTEXT
 
lnResult = SQLEXEC(lnConn, lcSql, "crsProducts")
IF lnResult < 0
	=AERROR(laError)
	? laError[1,2]
	RETURN
ENDIF	
 
BROWSE LAST NOWAIT