Home » Pages » Visual Foxpro

Loading XML into a WEB Browser Control from Variable

By Sergey - Posted on January 1st, 2008
Tagged:

The code below uses default Internet Explorer XSLT to convert XML into HTML.

This is sample code. Add error handling and adjust to your requirements as necessary.

lcXml = mytable.mymemo
lnLoadTimeout = 10       && seconds
WITH Thisform.oWeb.OBJECT
	.Navigate("about:blank")
	&& Wait for load completion
	lnStartSeconds = SECONDS()
	DO WHILE .ReadyState <> 4 ;
			AND (SECONDS()-lnStartSeconds <= lnLoadTimeout )
		DOEVENTS
	ENDDO
	&& Load IE default XML style sheet
	loXSL = CREATEOBJECT( "MSXML2.DOMDocument.3.0" )
	loXSL.async = .T.      &&required
	loXSL.load("res://msxml3.dll/DEFAULTSS.XSL")
	&& Load XML
	loXML = CREATEOBJECT( "MSXML2.DOMDocument.3.0" )
	loXML.loadXML( lcXml )
	&& Transform XML to HTML
	lcHtml = loXML.transformNode(loXSL)
	&& Load HTML into Web Browser Control
	.Document.Open()
	.Document.Write(lcHtml)
	.Document.Close()
	&& Wait for load completion
	lnStartSeconds = SECONDS()
	DO WHILE .ReadyState <> 4 ;
			AND (SECONDS()-lnStartSeconds <= lnLoadTimeout )
		DOEVENTS
	ENDDO
ENDWITH

See Also Loading HTML into a WEB Browser Control from Variable